mirror of
https://github.com/sunnypilot/sunnypilot.git
synced 2026-06-20 09:12:05 +08:00
Daniel Koepping
8c533b14c0
* test agnos18.1 in staging * loggerd: link va/va-drm/drm on larch64 * agnos 18.1 production
31 lines
1.1 KiB
Python
31 lines
1.1 KiB
Python
Import('env', 'arch', 'messaging', 'common', 'visionipc')
|
|
|
|
libs = [common, messaging, visionipc,
|
|
'avformat', 'avcodec', 'swresample', 'avutil', 'x264',
|
|
'pthread', 'z', 'm', 'zstd']
|
|
frameworks = []
|
|
|
|
src = ['logger.cc', 'zstd_writer.cc', 'video_writer.cc', 'encoder/encoder.cc', 'encoder/v4l_encoder.cc', 'encoder/jpeg_encoder.cc']
|
|
if arch != "larch64":
|
|
src += ['encoder/ffmpeg_encoder.cc']
|
|
libs += ['yuv']
|
|
if arch == "Darwin":
|
|
frameworks += ['VideoToolbox', 'CoreMedia', 'CoreFoundation', 'CoreVideo']
|
|
|
|
if arch != "Darwin":
|
|
libs += ['va', 'va-drm', 'drm']
|
|
|
|
if arch == "Darwin":
|
|
# exclude v4l
|
|
del src[src.index('encoder/v4l_encoder.cc')]
|
|
|
|
logger_lib = env.Library('logger', src)
|
|
libs.insert(0, logger_lib)
|
|
|
|
env.Program('loggerd', ['loggerd.cc'], LIBS=libs, FRAMEWORKS=frameworks)
|
|
env.Program('encoderd', ['encoderd.cc'], LIBS=libs + ["jpeg"], FRAMEWORKS=frameworks)
|
|
env.Program('bootlog.cc', LIBS=libs, FRAMEWORKS=frameworks)
|
|
|
|
if GetOption('extras'):
|
|
env.Program('tests/test_logger', ['tests/test_runner.cc', 'tests/test_logger.cc', 'tests/test_zstd_writer.cc'], LIBS=libs)
|