Import('env', 'arch', 'messaging', 'common', 'visionipc')

libs = [common, messaging, visionipc,
        'avformat', 'avcodec', 'swresample', 'avutil', 'x264',
        'pthread', 'z', 'm', 'zstd']
frameworks = []

src = ['logger.cc', 'zstd_writer.cc', 'video_writer.cc', 'encoder/encoder.cc', 'encoder/jpeg_encoder.cc']
if arch == "larch64":
  src += ['encoder/v4l_encoder.cc']
else:
  src += ['encoder/ffmpeg_encoder.cc']
  libs += ['yuv']
  if arch == "Darwin":
    frameworks += ['VideoToolbox', 'CoreMedia', 'CoreFoundation', 'CoreVideo']

if arch != "Darwin":
  libs += ['va', 'va-drm', 'drm']

logger_lib = env.Library('logger', src)
libs.insert(0, logger_lib)

env.Program('loggerd', ['loggerd.cc'], LIBS=libs, FRAMEWORKS=frameworks)
env.Program('encoderd', ['encoderd.cc'], LIBS=libs + ["jpeg"], FRAMEWORKS=frameworks)
env.Program('bootlog.cc', LIBS=libs, FRAMEWORKS=frameworks)

if GetOption('extras'):
  env.Program('tests/test_logger', ['tests/test_runner.cc', 'tests/test_logger.cc', 'tests/test_zstd_writer.cc'], LIBS=libs)