sunnypilot v2026.003.000 release

date: 2026-08-19T09:43:43
master commit: ba29a38507

msgq_repo/SConscript

@@ -0,0 +1,36 @@
+Import('env', 'envCython', 'common')
+
+
+visionipc_dir = Dir('msgq/visionipc')
+
+# Build msgq
+msgq_objects = env.SharedObject([
+  'msgq/ipc.cc',
+  'msgq/event.cc',
+  'msgq/impl_msgq.cc',
+  'msgq/impl_fake.cc',
+  'msgq/msgq.cc',
+])
+msgq = env.Library('msgq', msgq_objects)
+msgq_python = envCython.Program('msgq/ipc_pyx.so', 'msgq/ipc_pyx.pyx', LIBS=envCython["LIBS"]+[msgq]+common)
+
+# Build Vision IPC
+vipc_files = ['visionipc.cc', 'visionipc_server.cc', 'visionipc_client.cc']
+if File('/dev/ion').exists():
+  vipc_files += ['visionbuf_ion.cc']
+else:
+  vipc_files += ['visionbuf.cc']
+vipc_sources = [f'{visionipc_dir.abspath}/{f}' for f in vipc_files]
+
+vipc_objects = env.SharedObject(vipc_sources)
+visionipc = env.Library('visionipc', vipc_objects)
+
+
+vipc_libs = envCython["LIBS"] + [visionipc, msgq] + common
+envCython.Program(f'{visionipc_dir.abspath}/visionipc_pyx.so', f'{visionipc_dir.abspath}/visionipc_pyx.pyx',
+                  LIBS=vipc_libs)
+
+if GetOption('extras'):
+  env.Program('msgq/test_runner', ['msgq/msgq_tests.cc'], LIBS=[msgq]+common)
+
+Export('visionipc', 'msgq', 'msgq_python')