mirror of
https://github.com/infiniteCable2/openpilot.git
synced 2026-09-09 17:53:41 +08:00
DevTekVE
1a8dd310ae
* Add support for TinyGrad model runner processing Introduced a new function `is_tinygrad_model` to detect TinyGrad as an active model runner. Updated the `is_stock_model` logic to account for TinyGrad models and added a new process entry for TinyGrad in the model manager. This enables handling TinyGrad models alongside existing configurations. adding modeld back Add support for `modeld_v2` and update paths for consistency Updated `SConscript` files to integrate `modeld_v2` alongside `modeld` and adjusted script paths for correct metadata handling. Adjusted various configurations and scripts, such as `labeler.yaml` and `build_release.sh`, to include `modeld_v2` and ensure cohesive project structure. Refactor imports to use updated `modeld_v2` paths. Replaced outdated `modeld` references with their `modeld_v2` counterparts for consistency and clarity across the codebase. Also updated `.gitignore` to accommodate new directory structure. This change ensures better maintainability and alignment with the new directory schema. Refactor and reorganize modeld to sunnypilot/modeld_v2 structure. Moved and renamed `modeld` components to the new `sunnypilot/modeld_v2` directory for better organization and modularity. Updated imports and file references to align with the new structure, ensuring compatibility and functionality. Streamlined project structure to improve maintainability and future development. * typo * Use `stock` model runner and refactor model checks. Replaces outdated model detection logic with unified `stock` runner integration, simplifying the decision flow for model selection. Includes `stock` as a new enum in the `Runner` type and updates affected references accordingly. * Handle missing 'sim_pose' in model outputs gracefully. Added conditional checks to ensure the code handles cases where 'sim_pose' is absent in the model outputs. Fallback behaviors use 'plan' data when 'sim_pose' is unavailable, preventing potential errors and enhancing robustness.
75 lines
2.3 KiB
Cython
75 lines
2.3 KiB
Cython
# distutils: language = c++
|
|
# cython: c_string_encoding=ascii, language_level=3
|
|
|
|
import numpy as np
|
|
cimport numpy as cnp
|
|
from libc.string cimport memcpy
|
|
from libc.stdint cimport uintptr_t, uint8_t
|
|
|
|
from msgq.visionipc.visionipc cimport cl_mem
|
|
from msgq.visionipc.visionipc_pyx cimport VisionBuf, CLContext as BaseCLContext
|
|
from .commonmodel cimport CL_DEVICE_TYPE_DEFAULT, cl_get_device_id, cl_create_context, cl_release_context
|
|
from .commonmodel cimport mat3, ModelFrame as cppModelFrame, DrivingModelFrame as cppDrivingModelFrame, MonitoringModelFrame as cppMonitoringModelFrame
|
|
|
|
|
|
cdef class CLContext(BaseCLContext):
|
|
def __cinit__(self):
|
|
self.device_id = cl_get_device_id(CL_DEVICE_TYPE_DEFAULT)
|
|
self.context = cl_create_context(self.device_id)
|
|
|
|
def __dealloc__(self):
|
|
if self.context:
|
|
cl_release_context(self.context)
|
|
|
|
cdef class CLMem:
|
|
@staticmethod
|
|
cdef create(void * cmem):
|
|
mem = CLMem()
|
|
mem.mem = <cl_mem*> cmem
|
|
return mem
|
|
|
|
@property
|
|
def mem_address(self):
|
|
return <uintptr_t>(self.mem)
|
|
|
|
def cl_from_visionbuf(VisionBuf buf):
|
|
return CLMem.create(<void*>&buf.buf.buf_cl)
|
|
|
|
|
|
cdef class ModelFrame:
|
|
cdef cppModelFrame * frame
|
|
cdef int buf_size
|
|
|
|
def __dealloc__(self):
|
|
del self.frame
|
|
|
|
def prepare(self, VisionBuf buf, float[:] projection):
|
|
cdef mat3 cprojection
|
|
memcpy(cprojection.v, &projection[0], 9*sizeof(float))
|
|
cdef cl_mem * data
|
|
data = self.frame.prepare(buf.buf.buf_cl, buf.width, buf.height, buf.stride, buf.uv_offset, cprojection)
|
|
return CLMem.create(data)
|
|
|
|
def buffer_from_cl(self, CLMem in_frames):
|
|
cdef unsigned char * data2
|
|
data2 = self.frame.buffer_from_cl(in_frames.mem, self.buf_size)
|
|
return np.asarray(<cnp.uint8_t[:self.buf_size]> data2)
|
|
|
|
|
|
cdef class DrivingModelFrame(ModelFrame):
|
|
cdef cppDrivingModelFrame * _frame
|
|
|
|
def __cinit__(self, CLContext context, int buffer_length=2):
|
|
self._frame = new cppDrivingModelFrame(context.device_id, context.context, buffer_length)
|
|
self.frame = <cppModelFrame*>(self._frame)
|
|
self.buf_size = self._frame.buf_size
|
|
|
|
cdef class MonitoringModelFrame(ModelFrame):
|
|
cdef cppMonitoringModelFrame * _frame
|
|
|
|
def __cinit__(self, CLContext context):
|
|
self._frame = new cppMonitoringModelFrame(context.device_id, context.context)
|
|
self.frame = <cppModelFrame*>(self._frame)
|
|
self.buf_size = self._frame.buf_size
|
|
|