mirror of
https://github.com/firestar5683/StarPilot.git
synced 2026-10-27 16:43:59 +08:00
firestar5683
22a8575199
Keep official openpilot ancestry and dependency licenses. Store resources directly in Git, remove LFS setup requirements, and leave the downloadable big model outside the source tree.
37 lines
1.1 KiB
Python
37 lines
1.1 KiB
Python
Import('env', 'envCython', 'common')
|
|
|
|
|
|
visionipc_dir = Dir('msgq/visionipc')
|
|
|
|
# Build msgq
|
|
msgq_objects = env.SharedObject([
|
|
'msgq/ipc.cc',
|
|
'msgq/event.cc',
|
|
'msgq/impl_msgq.cc',
|
|
'msgq/impl_fake.cc',
|
|
'msgq/msgq.cc',
|
|
])
|
|
msgq = env.Library('msgq', msgq_objects)
|
|
msgq_python = envCython.Program('msgq/ipc_pyx.so', 'msgq/ipc_pyx.pyx', LIBS=envCython["LIBS"]+[msgq]+common)
|
|
|
|
# Build Vision IPC
|
|
vipc_files = ['visionipc.cc', 'visionipc_server.cc', 'visionipc_client.cc']
|
|
if File('/dev/ion').exists():
|
|
vipc_files += ['visionbuf_ion.cc']
|
|
else:
|
|
vipc_files += ['visionbuf.cc']
|
|
vipc_sources = [f'{visionipc_dir.abspath}/{f}' for f in vipc_files]
|
|
|
|
vipc_objects = env.SharedObject(vipc_sources)
|
|
visionipc = env.Library('visionipc', vipc_objects)
|
|
|
|
|
|
vipc_libs = envCython["LIBS"] + [visionipc, msgq] + common
|
|
envCython.Program(f'{visionipc_dir.abspath}/visionipc_pyx.so', f'{visionipc_dir.abspath}/visionipc_pyx.pyx',
|
|
LIBS=vipc_libs)
|
|
|
|
if GetOption('extras'):
|
|
env.Program('msgq/test_runner', ['msgq/msgq_tests.cc'], LIBS=[msgq]+common)
|
|
|
|
Export('visionipc', 'msgq', 'msgq_python')
|